home *** CD-ROM | disk | FTP | other *** search
/ Collection of Tools & Utilities / Collection of Tools and Utilities.iso / clipper / nfsrc21.zip / SHADOW.ASM < prev    next >
Encoding:
Assembly Source File  |  1992-10-16  |  6.1 KB  |  155 lines
  1. ; File......: SHADOW.ASM
  2. ; Author....: Ted Means
  3. ; Date......: $Date:   16 Oct 1992 00:07:06  $
  4. ; Revision..: $Revision:   1.4  $
  5. ; Log file..: $Logfile:   C:/nanfor/src/shadow.asv  $
  6. ; 
  7. ; This is an original work by Ted Means and is placed in the
  8. ; public domain.
  9. ;
  10. ; Modification history:
  11. ; ---------------------
  12. ;
  13. ; $Log:   C:/nanfor/src/shadow.asv  $
  14. ;  
  15. ;     Rev 1.4   16 Oct 1992 00:07:06   GLENN
  16. ;  Just making sure we had Ted's current revision.
  17. ;  
  18. ;     Rev 1.3   28 Sep 1992 21:41:06   GLENN
  19. ;  Ted Means completely and totally rewrote this to compile under TASM's
  20. ;  IDEAL mode, with more features.  See the documentation.  It should be
  21. ;  compatible with the old Reginald Walton function, but is much faster.
  22. ;  
  23. ;     Rev 1.2   15 Aug 1991 23:07:26   GLENN
  24. ;  Forest Belt proofread/edited/cleaned up doc
  25. ;  
  26. ;     Rev 1.1   11 May 1991 00:29:22   GLENN
  27. ;  Major re-write by Ted Means.  He sped it up.  It will also cooperate
  28. ;  with Clipper's internal _gtmaxrow and _gtmaxcol settings.  
  29. ;  
  30. ;     Rev 1.0   02 Apr 1991 18:25:40   GLENN
  31. ;  Nanforum Toolkit
  32. ;
  33. ;
  34.  
  35. ;  $DOC$
  36. ;  $FUNCNAME$
  37. ;      FT_SHADOW()
  38. ;  $CATEGORY$
  39. ;      Video
  40. ;  $ONELINER$
  41. ;      Draw a non-destructive shadow on the screen
  42. ;  $SYNTAX$
  43. ;     FT_SHADOW( <nTop>, <nLeft>, <nBottom>, <nRight>, <nAttr> ) -> NIL
  44. ;  $ARGUMENTS$
  45. ;     <nTop>    is the top row of the shadow area.
  46. ;     <nLeft>   is the upper left column of the shadow area.
  47. ;     <nBottom> is the bottom row of the shadow area.
  48. ;     <nRight>  is the lower right column of the shadow area.
  49. ;     <nAttr>   is the screen attribute to use for drawing the shadow.
  50. ;  $RETURNS$
  51. ;     NIL
  52. ;  $DESCRIPTION$
  53. ;     This function allows you to implement the popular "shadow effect."  It
  54. ;     draws a shadow using the specified screen coordinates.  The entire
  55. ;     specified region is shadowed.
  56. ;
  57. ;     *** INTERNALS ALERT ***  This function uses several Clipper internal 
  58. ;     routines.  If using internals scares you, then stay away from this
  59. ;     function, you gutless weasel.  The use of the internals helps to make
  60. ;     the function more well-behaved.  Clipper's display context is not
  61. ;     violated -- if you use dispbegin() before drawing the shadow, it will
  62. ;     not appear until the corresponding call to dispend().  This makes for
  63. ;     much smoother screen i/o if you have several screen objects that
  64. ;     you wish to shadow.
  65. ;
  66. ;     The source code is written to TASM IDEAL mode.
  67. ;  $EXAMPLES$
  68. ;     FT_Shadow(10,10,10,50, 8)  // draw a dim shadow
  69. ;        
  70. ;     FT_Shadow(10,10,10,40,47)  // draw a green shadow
  71. ;  $END$
  72.  
  73. IDEAL                                        ; Invoke TASM IDEAL mode
  74.  
  75. Public   FT_Shadow
  76.  
  77. Extrn    __ParNI:Far
  78. Extrn    __xGrab:Far
  79. Extrn    __xFree:Far
  80. Extrn    __gtSave:Far                        ; INTERNAL!!!
  81. Extrn    __gtRest:Far                        ; INTERNAL!!!
  82.  
  83. nTop     EQU       Word Ptr BP - 2
  84. nLeft    EQU       Word Ptr BP - 4
  85. nBottom  EQU       Word Ptr BP - 6
  86. nRight   EQU       Word Ptr BP - 8
  87. nAttr    EQU       Byte Ptr BP - 10
  88. nSize    EQU       Word Ptr BP - 12
  89.  
  90. Segment  _NanFor   Word      Public    "CODE"
  91.          Assume    CS:_NanFor
  92.  
  93. Proc     FT_Shadow Far
  94.  
  95.          Push      BP                        ; Save BP
  96.          Mov       BP,SP                     ; Set up stack reference
  97.          Sub       SP,12                     ; Allocate locals
  98.  
  99.          Mov       CX,5                      ; Set param count
  100. @@Coord: Push      CX                        ; Put on stack
  101.          Call      __ParNI                   ; Retrieve param
  102.          Pop       CX                        ; Get count back
  103.          Push      AX                        ; Put value on stack
  104.          Loop      @@Coord                   ; Get next value
  105.  
  106.          Pop       [nTop]                    ; Get top coordinate
  107.          Pop       [nLeft]                   ; Get left coordinate
  108.          Pop       [nBottom]                 ; Get bottom coordinate
  109.          Pop       [nRight]                  ; Get right coordinate
  110.          Pop       [Word Ptr BP - 10]        ; Get attribute
  111.  
  112.          Mov       AX,[nBottom]              ; Load bottom coordinate
  113.          Sub       AX,[nTop]                 ; Subtract top
  114.          Inc       AX                        ; Calc length
  115.  
  116.          Mov       DX,[nRight]               ; Load right coordinate
  117.          Sub       DX,[nLeft]                ; Subtract left
  118.          Inc       DX                        ; Calc width
  119.          Mul       DX                        ; Calc buffer size
  120.          Mov       [nSize],AX                ; Store size
  121.  
  122.          SHL       AX,1                      ; Account for attribute bytes
  123.          Push      AX                        ; Put size on stack
  124.          Call      __xGrab                   ; Allocate virtual memory
  125.  
  126.          Push      DX                        ; Put buffer segment on stack
  127.          Push      AX                        ; Put buffer offset on stack
  128.          Push      [nRight]
  129.          Push      [nBottom]                 ; Get bottom coordinate
  130.          Push      [nLeft]
  131.          Push      [nTop]                    ; Get top row
  132.          Call      __gtSave                  ; Save screen image
  133.  
  134.          Mov       BX,SP                     ; Point BX to buffer pointer
  135.          Mov       AL,[nAttr]                ; Get attribute
  136.          Mov       CX,[nSize]                ; Get length
  137.          Push      DI                        ; Save DI
  138.          LES       DI,[SS:BX + 8]            ; Load pointer to buffer
  139. @@Top:   Inc       DI                        ; Point to attribute byte
  140.          Stosb                               ; Set attribute
  141.          Loop      @@Top                     ; Do next byte
  142.          Pop       DI                        ; Restore DI
  143.          Call      __gtRest                  ; Put shadowed image onscreen
  144.  
  145. @@Done:  Add       SP,8                      ; Remove params from stack
  146.          Call      __xFree                   ; Free buffer
  147.          Mov       SP,BP                     ; Realign stack
  148.          Pop       BP                        ; Restore BP
  149.          Ret
  150. Endp     FT_Shadow
  151. Ends     _NanFor
  152. End
  153.  
  154.  
  155.